bullets can be fired by the player

Author: Acepie

gleam.toml

@@ -15,7 +15,7 @@ target = "javascript"
 
 [dependencies]
 gleam_stdlib = ">= 0.36.0 and < 2.0.0"
-p5js_gleam = ">= 2.0.0 and < 3.0.0"
+p5js_gleam = ">= 2.0.1 and < 3.0.0"
 prng = ">= 3.0.2 and < 4.0.0"
 gleam_community_maths = ">= 1.1.0 and < 2.0.0"
 

manifest.toml

@@ -16,7 +16,7 @@ packages = [
   { name = "gleam_json", version = "1.0.0", build_tools = ["gleam"], requirements = ["gleam_stdlib", "thoas"], otp_app = "gleam_json", source = "hex", outer_checksum = "8B197DD5D578EA6AC2C0D4BDC634C71A5BCA8E7DB5F47091C263ECB411A60DF3" },
   { name = "gleam_stdlib", version = "0.37.0", build_tools = ["gleam"], requirements = [], otp_app = "gleam_stdlib", source = "hex", outer_checksum = "5398BD6C2ABA17338F676F42F404B9B7BABE1C8DC7380031ACB05BBE1BCF3742" },
   { name = "glint", version = "0.18.1", build_tools = ["gleam"], requirements = ["gleam_community_ansi", "gleam_community_colour", "gleam_stdlib", "snag"], otp_app = "glint", source = "hex", outer_checksum = "5FB54D7732B4105E4AF4D89A7EE6D5E8CF33DA13A3575D0C6ECE470B97958454" },
-  { name = "p5js_gleam", version = "2.0.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "p5js_gleam", source = "hex", outer_checksum = "28CBB1EE158BB025B122E3BB33645B8C60FA4EB7BBDBE2A16E08C0A0638150FB" },
+  { name = "p5js_gleam", version = "2.0.1", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "p5js_gleam", source = "hex", outer_checksum = "2EA1C1FDB1D2748A7B02A786497BB50F7B86648C331D8A4E1274313F8F37C749" },
   { name = "prng", version = "3.0.2", build_tools = ["gleam"], requirements = ["gleam_bitwise", "gleam_stdlib"], otp_app = "prng", source = "hex", outer_checksum = "C61B103F9AF5031ADAA35187CCE7130845EF5088D88FD084E5995D4FBEC9D745" },
   { name = "ranger", version = "1.2.0", build_tools = ["gleam"], requirements = ["gleam_stdlib"], otp_app = "ranger", source = "hex", outer_checksum = "1566C272B1D141B3BBA38B25CB761EF56E312E79EC0E2DFD4D3C19FB0CC1F98C" },
   { name = "simplifile", version = "1.7.0", build_tools = ["gleam"], requirements = ["filepath", "gleam_stdlib"], otp_app = "simplifile", source = "hex", outer_checksum = "1D5DFA3A2F9319EC85825F6ED88B8E449F381B0D55A62F5E61424E748E7DDEB0" },
@@ -30,6 +30,6 @@ packages = [
 esgleam = { version = ">= 0.6.0 and < 1.0.0" }
 gleam_community_maths = { version = ">= 1.1.0 and < 2.0.0" }
 gleam_stdlib = { version = ">= 0.36.0 and < 2.0.0" }
-p5js_gleam = { version = ">= 2.0.0 and < 3.0.0"}
+p5js_gleam = { version = ">= 2.0.1 and < 3.0.0"}
 prng = { version = ">= 3.0.2 and < 4.0.0" }
 startest = { version = ">= 0.2.0 and < 1.0.0" }

src/bullet.gleam

@@ -0,0 +1,73 @@
+import p5js_gleam.{type P5}
+import p5js_gleam/bindings as p5
+import utils
+import vector.{type Vector}
+
+const time_alive = 400
+
+const bullet_size = 6.0
+
+const bullet_speed = 5.0
+
+pub const player_damage = 10
+
+pub const enemy_damage = 5
+
+/// Represents a fired bullet.
+pub type Bullet {
+  /// Represents a fired bullet.
+  Bullet(
+    /// The bullet's current position in the dungeon.
+    position: Vector,
+    /// The bullet's current velocity.
+    velocity: Vector,
+    /// Was the bullet fired by the player.
+    belongs_to_player: Bool,
+    /// The time the bullet was spawned.
+    time_spawned: Int,
+  )
+}
+
+/// Spawns a bullet at the given position going in the given direction.
+pub fn spawn_bullet(
+  position: Vector,
+  direction: Vector,
+  belongs_to_player: Bool,
+) -> Bullet {
+  Bullet(
+    position: position,
+    velocity: vector.multiply(vector.normalize(direction), bullet_speed),
+    belongs_to_player: belongs_to_player,
+    time_spawned: utils.now_in_milliseconds(),
+  )
+}
+
+/// Advances a bullet forward.
+pub fn advance_bullet(bullet: Bullet) -> Bullet {
+  Bullet(..bullet, position: vector.add(bullet.position, bullet.velocity))
+}
+
+/// Should the bullet be alive.
+pub fn is_still_alive(bullet: Bullet) -> Bool {
+  bullet.time_spawned + time_alive > utils.now_in_milliseconds()
+}
+
+/// Checks if the object at the given position with given radius collides with the bullet.
+pub fn collides_with(bullet: Bullet, position: Vector, size: Float) -> Bool {
+  vector.distance(bullet.position, position)
+  <. size /. 2.0 +. bullet_size /. 2.0
+}
+
+const player_bullet = "#3030ff"
+
+const enemy_bullet = "#f4424b"
+
+/// Renders the bullet to the screen.
+pub fn draw(p: P5, bullet: Bullet) {
+  p5.no_stroke(p)
+  case bullet.belongs_to_player {
+    True -> p5.fill(p, player_bullet)
+    False -> p5.fill(p, enemy_bullet)
+  }
+  p5.circle(p, bullet.position.x, bullet.position.y, bullet_size)
+}

src/bullet_heck_gleam.gleam

@@ -1,4 +1,7 @@
+import bullet
 import dungeon
+import gleam/bool
+import gleam/list
 import p5js_gleam.{type P5}
 import p5js_gleam/bindings as p5
 import player
@@ -7,10 +10,12 @@ import vector
 /// Represents the overall game state
 type WorldState {
   /// State of the world when the game is active
-  GameRunning(dungeon: dungeon.Dungeon, player: player.Player)
-  // bullets: List(Bullet),
+  GameRunning(
+    dungeon: dungeon.Dungeon,
+    player: player.Player,
+    bullets: List(bullet.Bullet),
+  )
   // enemies: List(Enemy),
-  // player: Player,
 }
 
 fn setup(p: P5) -> WorldState {
@@ -20,13 +25,15 @@ fn setup(p: P5) -> WorldState {
   GameRunning(
     dungeon,
     player.new_player(vector.Vector(canvas_size /. 2.0, canvas_size /. 2.0, 0.0)),
+    [],
   )
 }
 
 fn draw(p: P5, state: WorldState) {
   p5.background(p, "#000000")
   dungeon.draw(p, state.dungeon)
   player.draw(p, state.player)
+  list.each(state.bullets, bullet.draw(p, _))
 }
 
 fn on_key_pressed(key: String, _: Int, state: WorldState) -> WorldState {
@@ -50,43 +57,81 @@ fn on_key_released(key: String, _: Int, state: WorldState) -> WorldState {
   }
 }
 
-fn on_mouse_moved(x: Float, y: Float, state: WorldState) -> WorldState {
+fn on_mouse_clicked(x: Float, y: Float, state: WorldState) -> WorldState {
+  let firing_direction =
+    vector.vector_2d(vector.subtract(
+      vector.Vector(x, y, 0.0),
+      state.player.position,
+    ))
+  let player.Player(position: p, ..) = state.player
   GameRunning(
     ..state,
-    player: player.look_toward(state.player, vector.Vector(x, y, 0.0)),
+    bullets: [
+      bullet.spawn_bullet(vector.Vector(p.x, p.y, 0.0), firing_direction, True),
+      ..state.bullets
+    ],
   )
 }
 
 fn on_tick(state: WorldState) -> WorldState {
+  let GameRunning(dungeon, player, bullets) = state
   // Attempt to move player
-  let old_position = state.player.position
-  let moved = player.move(state.player)
-  let player = case
-    dungeon.can_move(state.dungeon, old_position, moved.position)
-  {
+  let old_position = player.position
+  let moved = player.move(player)
+  let player = case dungeon.can_move(dungeon, old_position, moved.position) {
     True -> moved
     // If they can't move then just apply gravity
     False ->
       player.Player(
-        ..state.player,
+        ..player,
         position: vector.Vector(
           old_position.x,
           old_position.y,
-          old_position.z +. state.player.velocity.z,
+          old_position.z +. player.velocity.z,
         ),
       )
   }
 
   let player = player.update_velocity(player)
   let player = player.apply_gravity(player)
-  GameRunning(..state, player: player)
+
+  let bullets =
+    bullets
+    |> list.filter(bullet.is_still_alive)
+
+  let #(bullets, player) =
+    list.fold(bullets, #([], player), fn(acc, b) {
+      // If the bullet hits a wall then remove it
+      use <- bool.guard(
+        !dungeon.can_move(
+          dungeon,
+          b.position,
+          bullet.advance_bullet(b).position,
+        ),
+        acc,
+      )
+
+      // Check if the bullet collides with something it can hit
+      let #(bullets, player) = acc
+      let player = case
+        !b.belongs_to_player
+        && bullet.collides_with(b, player.position, player.player_size)
+      {
+        True -> player.apply_damage(player, bullet.enemy_damage)
+        False -> player
+      }
+
+      #([bullet.advance_bullet(b), ..bullets], player)
+    })
+
+  GameRunning(..state, player: player, bullets: bullets)
 }
 
 pub fn main() {
   p5js_gleam.create_sketch(init: setup, draw: draw)
   |> p5js_gleam.set_on_key_pressed(on_key_pressed)
   |> p5js_gleam.set_on_key_released(on_key_released)
-  |> p5js_gleam.set_on_mouse_moved(on_mouse_moved)
+  |> p5js_gleam.set_on_mouse_clicked(on_mouse_clicked)
   |> p5js_gleam.set_on_tick(on_tick)
   |> p5.start_sketch
 }

src/player.gleam

@@ -4,7 +4,7 @@ import p5js_gleam/bindings as p5
 import utils
 import vector.{type Vector}
 
-const player_size = 10.0
+pub const player_size = 10.0
 
 const max_speed = 4.0
 
@@ -30,8 +30,6 @@ pub type Player {
     velocity: Vector,
     /// The character's current acceleration.
     acceleration: Vector,
-    /// The direction the player is firing relative to the player's position
-    firing_direction: Vector,
     /// Last time that the player fired a bullet
     last_fire_time: Int,
     /// Last time that the player was hit
@@ -49,7 +47,6 @@ pub fn new_player(initial_position: Vector) -> Player {
     position: initial_position,
     velocity: vector.Vector(0.0, 0.0, 0.0),
     acceleration: vector.Vector(0.0, 0.0, 0.0),
-    firing_direction: vector.Vector(0.0, 0.0, 0.0),
     last_fire_time: 0,
     last_hit_time: 0,
     current_health: base_max_health,
@@ -149,7 +146,7 @@ pub fn stop_y(player: Player) -> Player {
 
 const player_gravity_strength = 0.02
 
-// Applies gravity to the velocityy and resets z position to floor when appropriate.
+/// Applies gravity to the velocity and resets z position to floor when appropriate.
 pub fn apply_gravity(player: Player) -> Player {
   let position = case player.position.z {
     z if z <. 0.0 -> vector.Vector(player.position.x, player.position.y, 0.0)
@@ -166,12 +163,9 @@ pub fn apply_gravity(player: Player) -> Player {
   )
 }
 
-/// Make player look towards a point.
-pub fn look_toward(player: Player, point: Vector) -> Player {
-  Player(
-    ..player,
-    firing_direction: vector.vector_2d(vector.subtract(point, player.position)),
-  )
+/// Applies damage to the player
+pub fn apply_damage(player: Player, damage: Int) -> Player {
+  Player(..player, current_health: player.current_health - damage)
 }
 
 /// Is the player currently dead.

test/bullet_test.gleam

@@ -0,0 +1,38 @@
+import bullet.{type Bullet, Bullet}
+import startest.{describe, it}
+import startest/expect
+import vector.{Vector}
+
+pub fn bullet_tests() {
+  describe("bullet", [
+    it("advance_bullet", fn() {
+      expect.to_equal(
+        bullet.advance_bullet(Bullet(
+          Vector(0.0, 0.0, 0.0),
+          Vector(5.0, 0.0, 0.0),
+          True,
+          0,
+        )),
+        Bullet(Vector(5.0, 0.0, 0.0), Vector(5.0, 0.0, 0.0), True, 0),
+      )
+    }),
+    it("collides_with", fn() {
+      expect.to_equal(
+        bullet.collides_with(
+          Bullet(Vector(0.0, 0.0, 0.0), Vector(5.0, 0.0, 0.0), True, 0),
+          Vector(10.0, 0.0, 0.0),
+          1.0,
+        ),
+        False,
+      )
+      expect.to_equal(
+        bullet.collides_with(
+          Bullet(Vector(0.0, 0.0, 0.0), Vector(5.0, 0.0, 0.0), True, 0),
+          Vector(0.0, 0.0, 0.0),
+          1.0,
+        ),
+        True,
+      )
+    }),
+  ])
+}